Basic Oscilloscope Using Arduino

As I am a poor person ,I can not afford an oscilloscope even most entry one. Currently I am working on switching power converters so I badly need to see the waveform. 
Then I thought to build a DIY scope with the components I already have. I searched the web and found the solution.

I have arduino uno and downloaded Processing IDE from this link http://processing.org/

I used 555 timer as a simple square wave oscillator. and connected it with arduino analog inputs. Connected arduino board with USB cable to my laptop.
now here I have done two steps .
Upload code to the arduino IDE.
code is here-

#define ANALOG_IN 0

void setup() {

  Serial.begin(9600); 

  //Serial.begin(115200); 

}

void loop() {

  int val = analogRead(ANALOG_IN);                                              

  Serial.write( 0xff );                                                         

  Serial.write( (val >> 8) & 0xff );                                            

  Serial.write( val & 0xff );

}

Step two

Upload code to the Processing IDE

Code is here-

import processing.serial.*;

Serial port;  // Create object from Serial class

int val;      // Data received from the serial port

int[] values;

float zoom;

void setup() 

{

  size(1280, 480);

  // Open the port that the board is connected to and use the same speed (9600 bps)

  port = new Serial(this, Serial.list()[0], 9600);

  values = new int[width];

  zoom = 1.0f;

  smooth();

}

int getY(int val) {

  return (int)(height - val / 1023.0f * (height - 1));

}

int getValue() {

  int value = -1;

  while (port.available() >= 3) {

    if (port.read() == 0xff) {

      value = (port.read() << 8) | (port.read());

    }

  }

  return value;

}

void pushValue(int value) {

  for (int i=0; i<width-1; i++)

    values[i] = values[i+1];

  values[width-1] = value;

}

void drawLines() {

  stroke(255);

  

  int displayWidth = (int) (width / zoom);

  

  int k = values.length - displayWidth;

  

  int x0 = 0;

  int y0 = getY(values[k]);

  for (int i=1; i<displayWidth; i++) {

    k++;

    int x1 = (int) (i * (width-1) / (displayWidth-1));

    int y1 = getY(values[k]);

    line(x0, y0, x1, y1);

    x0 = x1;

    y0 = y1;

  }

}

void drawGrid() {

  stroke(255, 0, 0);

  line(0, height/2, width, height/2);

}

void keyReleased() {

  switch (key) {

    case '+':

      zoom *= 2.0f;

      println(zoom);

      if ( (int) (width / zoom) <= 1 )

        zoom /= 2.0f;

      break;

    case '-':

      zoom /= 2.0f;

      if (zoom < 1.0f)

        zoom *= 2.0f;

      break;

  }

}

void draw()

{

  background(0);

  drawGrid();

  val = getValue();

  if (val != -1) {

    pushValue(val);

  }

  drawLines();

}

Here Is my Prototype-